# AppleScript : connect remote access configuration ?



## sbeck (1 Décembre 2000)

Hello,
Sous MacOs 8.6, je voudrai faire un script qui lance une configuration Remote Access.
Ce script d'école ne fonctionne pas, il lance la config active sous remote access et non celle demandée par le script ?

set the config_name to "FREESBEE"
try
	tell application "Pilotage réglages réseau"
		open database
		connect Remote Access configuration config_name
		close database
	end tell
on error
	try
		tell application "Pilotage réglages réseau" to close database
	on error
	end try
end try

J'ai essayé :
		begin transaction
		set activate of Remote Access configuration "FREESBEE" to true
  end transaction

Rien à faire. Après des heures de recherche, je ne sais plus quoi faire.
Merci pour votre aide.


----------



## Gwenhiver (8 Décembre 2000)

Salut ! Je viens de voir ton message, et il se trouve que j'avais écrit un script du même genre il y quelques mois. Depuis, j'ai trashé le script, mais je me rappelle que je m'étais inspiré d'un script qui figurait sur le CD d'installation de mon iMac. Je posterai le code de ce script en fin de soirée (je ne suis pas chez moi).
A tout à l'heure,
David


----------



## Gwenhiver (9 Décembre 2000)

Salut,

Voici donc le texte du script trouvé sur mon CD d'installation :



property kRANoError : 0
property kRAPortBusy : -7114

global theUserName
global theTelephone
global savedConfig

--	a run message is sent to the script application when it is launched.
on run

	set theUserName to text returned of (display dialog "Enter user name:" default answer "")

	set theTelephone to text returned of (display dialog "Enter telephone number:" default answer "")

	tell application "Pilotage réglages réseau"

		open database -- open the configuration database and begin a transaction	

		begin transaction -- begin a transaction		

		-- save the currently active configuration
		set savedConfig to every Remote Access configuration whose active is true

		-- make a new temporary configuration		
		make new Remote Access configuration "temporary" with properties ¬
			{active:true, phone number:theTelephone}

		tell Remote Access configuration "temporary"
			-- check if username given - otherwise use guest access
			if (theUserName ­ "") then
				set user name to theUserName
			else
				set guest access to true
			end if
		end tell

		end transaction

		try

			connect Remote Access configuration "temporary"

		on error errmsg number errnum

			if (errnum ­ kRANoError) and (errnum ­ kRAPortBusy) then
				display dialog "Error " & errnum & " was encountered when attempting to establish a Remote Access connection."
			end if

		end try

		begin transaction

		delete Remote Access configuration "temporary"

		set active of item 1 of savedConfig to true

		end transaction

		close database

		quit

	end tell

end run



C'est un peu long, mais ça fonctionne. Tu peux modifier le script pour qu'il ne te demande pas à chaque fois quel est le nom d'utilisateur, le numéro de téléphone, et le mot de passe.
Si tu as des problèmes, n'hésite pas à poster tes questions.

David


----------

