# Automator : JPG vers PDF



## MarcPJ31 (20 Juin 2011)

Bonjour,

Je travaille actuellement avec Leopard.

J'aimerais concevoir un programme avec Automator permettant de transformer un dossier avec plein de photos (en JPG, PNG...) dans un seul PDF.

Assez facilement, je suis arrivé à faire un fichier PDF avec automator : appelé "Images.pdf". Le script automator contient 2 éléments.



Toutefois, j'aimerais ajouter le renommage de ce fichier PDF comme le nom du répertoire (en y accolant l'extension PDF). 

En gros, voici larborescence avant :
.../Mon_fils_a_velo/IMG_1001.jpg
.../Mon_fils_a_velo/IMG_1002.jpg

Voici larborescence après :
.../Mon_fils_a_velo/IMG_1001.jpg
.../Mon_fils_a_velo/IMG_1002.jpg
.../Mon_fils_a_velo.pdf


Je n'y arrive pas, avec automator.
Est-ce possible ?

Mon but est de faire un clic droit sur le répertoire de choisir : Automator / Mon_script_de_transformation.workflow et que tout se fasse automatiquement.

Merci d'avance pour toutes vos pistes de recherche.

-- Marc


----------



## Anonyme (21 Juin 2011)

Bonjour,

C'est possible avec deux actions "Exécuter un script AppleScript"

Ajoute l'action "Exécuter un script AppleScript" au début du workflow
le code sera 
	
	



```
on run {input, parameters}
	set tempFile to quoted form of POSIX path of ((path to temporary items as string) & "_t_path_To_Folder_.txt")
	set tfile to quoted form of POSIX path of (get item 1 of input)
	do shell script "folderPath=$(/usr/bin/dirname " & tfile & ");echo \"$folderPath\" > " & tempFile
	return input
end run
```

Ajoute l'autre action "Exécuter un script AppleScript" après l'action "*Nouveau PDF à partir des images*"
le code sera 
	
	



```
on run {input, parameters}
	set tempfile to alias ((path to temporary items as string) & "_t_path_To_Folder_.txt")
	set folderPath to paragraph 1 of (read tempfile as «class utf8»)
	set folderPath to (POSIX file (folderPath & "/") as string) as alias
	set tPDF to item 1 of input
	tell application "Finder"
		set tname to name of folderPath
		move tPDF to folderPath
		if exists file (tname & ".pdf") in folderPath then
			set i to 1
			repeat
				if not (exists file (tname & i & ".pdf") in folderPath) then exit repeat
				set i to i + 1
			end repeat
			set tname to tname & i
		end if
		set name of tPDF to (tname & ".pdf")
	end tell
	do shell script "/bin/rm -f " & quoted form of POSIX path of tempfile
	return tPDF
end run
```


----------

